windows2008、2012及以上一键安装php5.6、7.0

:: $Name:         php56-70.bat
:: $Version:      v1.1
:: $Function:     一键安装php5.6、7.0
:: $Create Date:  2017-4-18
:: $Description:  1、一键安装php5.6、7.0
::                2、支持预装环境及纯净版
::#v1.1
::优化php5.6 zend、op加速组件
::优化php7.0缓存目录，安装时做了智能判断目录是否存在，权限是否正确
::
@echo off&setlocal enabledelayedexpansion
set baseurl=http://download.myhostadmin.net
if not exist %cd%\wget.exe (
	echo.
	echo 缺少wget.exe程序
	explorer.exe %baseurl%/wget.exe
	echo 正在下载wget.exe必要程序，请保存到当前目录下
	echo 下载完成后按任意键继续
	pause
)
if not exist %cd%\wget.exe (
	echo.
	echo 自动头下载失败请访问 %baseurl%/wget.exe 手动下载
	echo 并保存到当前目录
	echo.
	pause
	exit
)
echo.
:menu
echo.
echo 一键安装php5.6、7.0
echo.
echo 请选择php版本: 

echo   1 php5.6
echo   2 php7.0 
echo   0 退出

set /p first=

if %first% ==1 call:phpinstall 5.6
if %first% ==2 call:phpinstall 7.0
if %first% ==0 goto exit

:download
echo.
echo 正在下载所需组件
echo.
%cd%\wget.exe %~1 -O %~2
goto:eof

:phpinstall
echo.
if not exist D:\SOFT_PHP_PACKAGE (
echo 请输入安装路径
echo 比如：d:\php
set /p "a=："
) else set a=D:\SOFT_PHP_PACKAGE
echo 检查 php%~1 缓存目录是否存在 ……
echo.
if not exist D:\SOFT_PHP_PACKAGE\phptmp (
	md D:\SOFT_PHP_PACKAGE\phptmp
	echo Y|C:\Windows\system32\cacls D:\SOFT_PHP_PACKAGE\phptmp /T /C /P administrators:F everyone:F
)
set b=%a%\php%~1
echo 开始安装php%~1 ……
if not exist %cd%\php%~1.rar (
	call:download %baseurl%/php/php%~1.rar %cd%\php%~1.rar	
)
"C:\Program Files\WinRAR\rar.exe" x -inul -o+  %cd%\php%~1.rar   %a%  -y
cls
echo Y|C:\Windows\system32\cacls %b% /T /C /P administrators:F everyone:R
if not exist %cd%\vcx86php%~1.exe (
	call:download %baseurl%/php/vcx86php%~1.exe %cd%\vcx86php%~1.exe
)
echo 正在安装VC组件 ……
%cd%\vcx86php%~1.exe /install /quiet /norestart

C:\Windows\System32\inetsrv\appcmd.exe set config  -section:system.webServer/fastCgi /+"[fullPath='%b%\php-cgi.exe',monitorChangesTo='%b%\php.ini',maxInstances='100',instanceMaxRequests='3000']" /commit:apphost
C:\Windows\System32\inetsrv\appcmd.exe set config  -section:system.webServer/fastCgi /+"[fullPath='%b%\php-cgi.exe',monitorChangesTo='%b%\php.ini',maxInstances='100',instanceMaxRequests='3000'].environmentVariables.[name='PHP_FCGI_MAX_REQUESTS',value='1000']" /commit:apphost
C:\Windows\System32\inetsrv\appcmd.exe set config  -section:system.webServer/fastCgi /+"[fullPath='%b%\php-cgi.exe',monitorChangesTo='%b%\php.ini',maxInstances='100',instanceMaxRequests='3000'].environmentVariables.[name='PHPRC',value='%b%']" /commit:apphost

goto end

:end
echo.
echo 需要重启iis才能生效，正在重启中……
C:\Windows\system32\iisreset
echo.
echo 已成功安装php%~1
echo.
echo 请使用建站助手创建站点，创建时请选择php5.3或5.4或5.5
echo.
echo 创建完成后请到iis管理器-找到对应站点-处理程序映射-找到php-可执行文件-5.6或7.0所在路径
echo.
echo.
echo   1 继续安装其他版本
echo   2 清理下载文件并退出
echo   0 退出
echo.
set /p choice=
if %choice% ==1 goto menu
if %choice% ==2 goto del
if %choice% ==0 goto exit

:del
echo.
echo 正在清理之前下载文件及文件夹……
echo.
for /f "delims=" %%i in ('dir /b /a-d "php*".rar') do del %%i  
for /f "delims=" %%i in ('dir /b /a-d "vcx86php*".exe') do del %%i  
pause
exit

:exit
exit